<SCRIPT RunAt=Server Language=VBScript>

'THIS CODE AND INFORMATION IS PROVIDED "AS IS" WITHOUT 
'WARRANTY OF ANY KIND, EITHER EXPRESSED OR IMPLIED, 
'INCLUDING BUT NOT LIMITED TO THE IMPLIED WARRANTIES 
'OF MERCHANTABILITY AND/OR FITNESS FOR A  PARTICULAR 
'PURPOSE

'------------------------------------------------------------------------------
'FILE DESCRIPTION: Sample Exchange Server Event Script 
'
'File Name: CounterVJ.txt
' 
'Note: CounterVJ.txt has a very small example of how to integrate VBScript and
'      JScript in the same event script.
'
' Copyright (c) Microsoft Corporation 1993-1997. All rights reserved.
'------------------------------------------------------------------------------

Option Explicit 

'------------------------------------------------------------------------------
' Localized strings
'------------------------------------------------------------------------------
' Put all localizable strings and constants here

'------------------------------------------------------------------------------
' Global Variables
'------------------------------------------------------------------------------

Dim g_bstrDebug    'Debug String
Dim g_bstrDebug2   'JScript Debug String

Dim g_CdoPR_CONTENT_COUNT
g_CdoPR_CONTENT_COUNT = &H36020003        'Message Count in Folder

'------------------------------------------------------------------------------
' Event Handlers
'------------------------------------------------------------------------------

' DESCRIPTION: This event is fired when a new message is added to the folder
Public Sub Folder_OnMessageCreated

    Call DebugAppend(vbCrLf&"COUNTERVJ - Folder_OnMessageCreated",False)
	Call SendResponseMessage    
    
    x = JScript.JTest("STRING PASSED TO JSCRIPT",err.number,err.description)

	Script.Response = g_bstrDebug + VbCrLf + "JSCRIPT INFO: " + g_bstrDebug2

End Sub

' DESCRIPTION: This event is fired when a message in the folder is changed
Public Sub MessageOnChange

    Call DebugAppend(vbCrLf&"COUNTERVJ - MessageOnChange",False)	
    Call SendResponseMessage
    Script.Response = g_bstrDebug
	
End Sub

' DESCRIPTION: This event is fired when a message is deleted from the folder
Public Sub Folder_OnMessageDeleted
	
    Script.Response = vbCrLf & "COUNTERVJ - Folder_OnMessageDeleted"
	
End Sub

' DESCRIPTION: This event is fired when the timer on the folder expires
Public Sub Folder_OnTimer

	Script.Response = vbCrLf & "COUNTERVJ - Folder_OnTimer"

End Sub

'-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
'                  PRIVATE FUNCTIONS/SUBS
'-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+

'------------------------------------------------------------------------------
'   Name: SendResponseMessage
'   Area: App
'   Desc: Get CDO objects and Send Message
'   Parm: None
'------------------------------------------------------------------------------

' DESCRIPTION: Get the details of the event that fired
Private Sub SendResponseMessage

    On Error Resume Next

    Dim CDOSession    'Session Object
	Dim oMsg          'Message Object
	Dim oFolder       'Current Folder Object
    Dim oFolderOutbox 'Outbox Folder Object
    Dim oMsgTarget   'Target Msg Object
    
    Dim iMsgCount
    
    'Javascript requires that this variable be initialized
    g_bstrDebug2 = ""
    		
	Set CDOSession = EventDetails.Session
	Call DebugAppend("EventDetails.Session Failed",True)
  
    Set oFolderOutbox = CDOSession.Outbox
    Call DebugAppend("CDOSession.Outbox",True)

	Set oFolder = CDOSession.GetFolder(EventDetails.FolderID, Null )
	Call DebugAppend("CDOSession.GetFolder",True)
	
    Set oMsgTarget = CDOSession.GetMessage( EventDetails.MessageID, Null )
	Call DebugAppend("CDOSession.GetMessage",True)

    iMsgCount = oFolder.Fields(g_CdoPR_CONTENT_COUNT)
    Call DebugAppend("oFolder.Fields(PR_CONTENT_COUNT)",True)

    'Create Message In Outbox
	Set oMsg = oFolderOutbox.Messages.Add( "A new message was added", "There are now " & iMsgCount & " messages in the folder")
	oMsg.Recipients.Add "", "", 1, oMsgTarget.Sender.ID
	oMsg.Recipients.Resolve(False)
	If oMsg.Recipients.Resolved = True Then
	   oMsg.Send
       If err.number <> 0 then
          Call DebugAppend("omsg.Send",True)
       
       Else
          Call DebugAppend("Message Sent",False)
       End If

    Else
       Call DebugAppend("Recipient.Resolve",True)   
    End If

    'Trap any errors in message creation/sending.
    Call DebugAppend("SendResponseMessage Sub",True)

End Sub


'------------------------------------------------------------------------------
'   Name: DebugAppend
'   Area: Debug
'   Desc: Simple Debugging Function
'   Parm: String Text, Bool ErrorFlag
'------------------------------------------------------------------------------

Private Sub DebugAppend(bstrParm,boolErrChkFlag)

   if boolErrChkFlag = True then
       if err.number <> 0 then
           g_bstrDebug = g_bstrDebug & bstrParm & " Failed: " & cstr(err.number) & err.description & vbCrLf
           err.clear
       end if

   else
       g_bstrDebug = g_bstrDebug & bstrParm & vbCrLf
   end if

End Sub


</SCRIPT>

<SCRIPT Language=JScript>

function JTest(jstrParm1,x,jstrParm3)
    {

    if (x > 0)
         {
         VBScript.g_bstrDebug2 = VBScript.g_bstrDebug2 + jstrParm1 + " - " + x + jstrParm3;
         }
    else
         {
         VBScript.g_bstrDebug2 = VBScript.g_bstrDebug2 + jstrParm1;
         }
   }
</SCRIPT>